path: root/apworld/client/player.gd

extends "res://scripts/nodes/player.gd"

signal evaluate_solvability

var compass


func _ready():
	var khl_script = load("res://scripts/nodes/keyHolderListener.gd")

	var pause_menu = get_node("pause_menu")
	pause_menu.layer = 3

	var ap = global.get_node("Archipelago")
	var gamedata = global.get_node("Gamedata")

	compass = global.get_node("Compass")
	compass.visible = ap.show_compass

	ap.start_batching_locations()

	# Block off roof access in Daedalus.
	if global.map == "daedalus" and not ap.daedalus_roof_access:
		_set_up_invis_wall(75.5, 11, -24.5, 1, 10, 49)
		_set_up_invis_wall(51.5, 11, -17, 16, 10, 1)
		_set_up_invis_wall(46, 10, -9.5, 1, 10, 10)
		_set_up_invis_wall(67.5, 11, 17, 16, 10, 1)
		_set_up_invis_wall(50.5, 11, 14, 10, 10, 1)
		_set_up_invis_wall(39, 10, 18.5, 1, 10, 22)
		_set_up_invis_wall(20, 15, 18.5, 1, 10, 16)
		_set_up_invis_wall(11.5, 15, 3, 32, 10, 1)
		_set_up_invis_wall(11.5, 16, -20, 14, 20, 1)
		_set_up_invis_wall(14, 16, -26.5, 1, 20, 4)
		_set_up_invis_wall(28.5, 20.5, -26.5, 1, 15, 25)
		_set_up_invis_wall(40.5, 20.5, -11, 30, 15, 1)
		_set_up_invis_wall(50.5, 15, 5.5, 7, 10, 1)
		_set_up_invis_wall(83.5, 33.5, 5.5, 1, 7, 11)
		_set_up_invis_wall(83.5, 33.5, -5.5, 1, 7, 11)

		var warp_exit_prefab = preload("res://objects/nodes/exit.tscn")
		var warp_exit = warp_exit_prefab.instantiate()
		warp_exit.name = "roof_access_blocker_warp_exit"
		warp_exit.position = Vector3(58, 10, 0)
		warp_exit.rotation_degrees.y = 90
		get_parent().add_child.call_deferred(warp_exit)

		var warp_enter_prefab = preload("res://objects/nodes/teleportAuto.tscn")
		var warp_enter = warp_enter_prefab.instantiate()
		warp_enter.target = warp_exit
		warp_enter.position = Vector3(76.5, 30, 1)
		warp_enter.scale = Vector3(4, 1.5, 1)
		warp_enter.rotation_degrees.y = 90
		get_parent().add_child.call_deferred(warp_enter)

	if global.map == "the_entry":
		# Remove door behind X1.
		var door_node = get_tree().get_root().get_node("/root/scene/Components/Doors/exit_1")
		door_node.handleTriggered()

		# Display win condition.
		var sign_prefab = preload("res://objects/nodes/sign.tscn")
		var sign1 = sign_prefab.instantiate()
		sign1.position = Vector3(-7, 5, -15.01)
		sign1.text = "victory"
		get_parent().add_child.call_deferred(sign1)

		var sign2 = sign_prefab.instantiate()
		sign2.position = Vector3(-7, 4, -15.01)
		sign2.text = "%s ending" % ap.kEndingNameByVictoryValue.get(ap.victory_condition, "?")

		var sign2_color = ap.kEndingNameByVictoryValue.get(ap.victory_condition, "coral").to_lower()
		if sign2_color == "white":
			sign2_color = "silver"

		sign2.material = load("res://assets/materials/%s.material" % sign2_color)
		get_parent().add_child.call_deferred(sign2)

		# Add the gift map entry panel if needed.
		if not ap.enable_gift_maps.is_empty():
			var panel_prefab = preload("res://objects/nodes/panel.tscn")
			var tpl_prefab = preload("res://objects/nodes/listeners/teleportListener.tscn")
			var wpl_prefab = preload("res://objects/nodes/listeners/worldportListener.tscn")

			var giftmap_parent = Node.new()
			giftmap_parent.name = "GiftMapEntrance"
			get_node("/root/scene/Components").add_child.call_deferred(giftmap_parent)

			var symbolless_player = ""
			for i in range(ap.client.ap_user.length()):
				if "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ".contains(
					ap.client.ap_user[i]
				):
					symbolless_player = symbolless_player + ap.client.ap_user[i].to_lower()

			var giftmap_panel = panel_prefab.instantiate()
			giftmap_panel.name = "Panel"
			giftmap_panel.position = Vector3(33.5, -190, 5.5)
			giftmap_panel.rotation_degrees = Vector3(-45, 0, 0)
			giftmap_panel.clue = "player"
			giftmap_panel.answer = symbolless_player

			if ap.enable_gift_maps.has("The Advanced"):
				var icely_panel = panel_prefab.instantiate()
				icely_panel.name = "IcelyPanel"
				icely_panel.answer = "icely"
				icely_panel.position = Vector3(33.5, -200, 5.5)
				giftmap_panel.proxies.append(NodePath("../IcelyPanel"))
				giftmap_parent.add_child.call_deferred(icely_panel)

				var icely_wpl = wpl_prefab.instantiate()
				icely_wpl.name = "IcelyWpl"
				icely_wpl.exit = "the_advanced"
				icely_wpl.senders.append(NodePath("../IcelyPanel"))
				giftmap_parent.add_child.call_deferred(icely_wpl)

			if ap.enable_gift_maps.has("The Charismatic"):
				var souvey_panel = panel_prefab.instantiate()
				souvey_panel.name = "SouveyPanel"
				souvey_panel.answer = "souvey"
				souvey_panel.position = Vector3(33.5, -210, 5.5)
				giftmap_panel.proxies.append(NodePath("../SouveyPanel"))
				giftmap_parent.add_child.call_deferred(souvey_panel)

				var souvey_wpl = wpl_prefab.instantiate()
				souvey_wpl.name = "SouveyWpl"
				souvey_wpl.exit = "the_charismatic"
				souvey_wpl.senders.append(NodePath("../SouveyPanel"))
				giftmap_parent.add_child.call_deferred(souvey_wpl)

			if ap.enable_gift_maps.has("The Crystalline"):
				var q_panel = panel_prefab.instantiate()
				q_panel.name = "QPanel"
				q_panel.answer = "q"
				q_panel.position = Vector3(33.5, -220, 5.5)
				giftmap_panel.proxies.append(NodePath("../QPanel"))
				giftmap_parent.add_child.call_deferred(q_panel)

				var q_wpl = wpl_prefab.instantiate()
				q_wpl.name = "QWpl"
				q_wpl.exit = "the_crystalline"
				q_wpl.senders.append(NodePath("../QPanel"))
				giftmap_parent.add_child.call_deferred(q_wpl)

			giftmap_parent.add_child.call_deferred(giftmap_panel)

			var giftmap_tpl = tpl_prefab.instantiate()
			giftmap_tpl.name = "PanelTeleporter"
			giftmap_tpl.teleport_point = Vector3(33.5, 1, 5.5)
			giftmap_tpl.teleport_rotate = Vector3(-45, 0, 0)
			giftmap_tpl.target_path = giftmap_panel
			giftmap_tpl.senders.append(
				NodePath("/root/scene/Components/Listeners/unlockReaderListenerDoubles")
			)
			giftmap_parent.add_child.call_deferred(giftmap_tpl)

	# Add the strict purple ending validation.
	if global.map == "the_sun_temple" and ap.strict_purple_ending:
		var panel_prefab = preload("res://objects/nodes/panel.tscn")
		var tpl_prefab = preload("res://objects/nodes/listeners/teleportListener.tscn")
		var reverse_prefab = preload("res://objects/nodes/listeners/reversingListener.tscn")

		var previous_panel = null
		var next_y = -100
		var words = ["quick", "brown", "fox", "jumps", "over", "the", "lazy", "dog"]
		for word in words:
			var panel = panel_prefab.instantiate()
			panel.position = Vector3(0, next_y, 0)
			next_y -= 10
			panel.clue = word
			panel.symbol = ""
			panel.answer = word
			panel.name = "EndCheck_%s" % word

			var tpl = tpl_prefab.instantiate()
			tpl.teleport_point = Vector3(0, 1, 0)
			tpl.teleport_rotate = Vector3(-45, 180, 0)
			tpl.target_path = panel
			tpl.name = "Teleport"

			if previous_panel == null:
				tpl.senders.append(NodePath("/root/scene/Panels/End/panel_24"))
			else:
				tpl.senders.append(NodePath("../../%s" % previous_panel.name))

			var reversing = reverse_prefab.instantiate()
			reversing.senders.append(NodePath(".."))
			reversing.name = "Reversing"
			tpl.senders.append(NodePath("../Reversing"))

			panel.add_child.call_deferred(tpl)
			panel.add_child.call_deferred(reversing)
			get_parent().get_node("Panels").add_child.call_deferred(panel)

			previous_panel = panel

		# Duplicate the doors that usually wait on EQUINOX. We can't set the senders
		# here for some reason so we actually set them in the door ready function.
		var endplat = get_node("/root/scene/Components/Doors/EndPlatform")
		var endplat2 = endplat.duplicate()
		endplat2.name = "spe_EndPlatform"
		endplat.get_parent().add_child.call_deferred(endplat2)
		endplat.queue_free()

		var entry2 = get_node("/root/scene/Components/Doors/entry_2")
		var entry22 = entry2.duplicate()
		entry22.name = "spe_entry_2"
		entry2.get_parent().add_child.call_deferred(entry22)
		entry2.queue_free()

	# Add the strict cyan ending validation.
	if global.map == "the_parthenon" and ap.strict_cyan_ending:
		var panel_prefab = preload("res://objects/nodes/panel.tscn")
		var tpl_prefab = preload("res://objects/nodes/listeners/teleportListener.tscn")
		var reverse_prefab = preload("res://objects/nodes/listeners/reversingListener.tscn")

		var previous_panel = null
		var next_y = -100
		var words = ["quick", "brown", "fox", "jumps", "over", "the", "lazy", "dog"]
		for word in words:
			var panel = panel_prefab.instantiate()
			panel.position = Vector3(0, next_y, 0)
			next_y -= 10
			panel.clue = word
			panel.symbol = "."
			panel.answer = "%s%s" % [word, word]
			panel.name = "EndCheck_%s" % word

			var tpl = tpl_prefab.instantiate()
			tpl.teleport_point = Vector3(0, 1, -11)
			tpl.teleport_rotate = Vector3(-45, 0, 0)
			tpl.target_path = panel
			tpl.name = "Teleport"

			if previous_panel == null:
				tpl.senderGroup.append(NodePath("/root/scene/Panels/Rulers"))
			else:
				tpl.senders.append(NodePath("../../%s" % previous_panel.name))

			var reversing = reverse_prefab.instantiate()
			reversing.senders.append(NodePath(".."))
			reversing.name = "Reversing"
			tpl.senders.append(NodePath("../Reversing"))

			panel.add_child.call_deferred(tpl)
			panel.add_child.call_deferred(reversing)
			get_parent().get_node("Panels").add_child.call_deferred(panel)

			previous_panel = panel

		# Duplicate the door that usually waits on the rulers. We can't set the
		# senders here for some reason so we actually set them in the door ready
		# function.
		var entry1 = get_node("/root/scene/Components/Doors/entry_1")
		var entry12 = entry1.duplicate()
		entry12.name = "spe_entry_1"
		entry1.get_parent().add_child.call_deferred(entry12)
		entry1.queue_free()

	# Move the Plaza RTE trigger outside of the turtle.
	if global.map == "the_plaza":
		var rte_trigger = get_node("/root/scene/Components/Warps/triggerArea")
		rte_trigger.position.z = 0

	# Add the mastery to The Advanced.
	if global.map == "the_advanced":
		var collectable_prefab = preload("res://objects/nodes/collectable.tscn")
		var saver_prefab = preload("res://objects/nodes/saver.tscn")
		var tpl_prefab = preload("res://objects/nodes/listeners/teleportListener.tscn")

		var mastery = collectable_prefab.instantiate()
		mastery.name = "collectable"
		mastery.position = Vector3(0, -200, -5)
		mastery.unlock_type = "smiley"
		mastery.material_override = load("res://assets/materials/gold.material")
		get_node("/root/scene/Components/Collectables").add_child.call_deferred(mastery)

		var tpl = tpl_prefab.instantiate()
		tpl.teleport_point = Vector3(0, 2, -5)
		tpl.teleport_rotate = Vector3(0, 0, 0)
		tpl.target_path = mastery
		tpl.name = "Teleport"
		tpl.senders.append(NodePath("/root/scene/Panels/Room_1/panel_29"))
		tpl.senders.append(NodePath("/root/scene/Panels/Room_1/panel_30"))
		tpl.senders.append(NodePath("/root/scene/Panels/Room_1/panel_31"))
		mastery.add_child.call_deferred(tpl)

		var saver = saver_prefab.instantiate()
		saver.name = "saver_collectables"
		saver.type = "collectables"
		saver.senderGroup.append(NodePath("/root/scene/Components/Collectables"))
		get_node("/root/scene").add_child.call_deferred(saver)

	# Add the mastery to The Charismatic.
	if global.map == "the_charismatic":
		var collectable_prefab = preload("res://objects/nodes/collectable.tscn")
		var saver_prefab = preload("res://objects/nodes/saver.tscn")

		var mastery = collectable_prefab.instantiate()
		mastery.name = "collectable"
		mastery.position = Vector3(-17, 2, -29)
		mastery.rotation_degrees = Vector3(0, 45, 0)
		mastery.unlock_type = "smiley"
		mastery.material_override = load("res://assets/materials/gold.material")
		get_node("/root/scene/Components/Collectables").add_child.call_deferred(mastery)

		var saver = saver_prefab.instantiate()
		saver.name = "saver_collectables"
		saver.type = "collectables"
		saver.senderGroup.append(NodePath("/root/scene/Components/Collectables"))
		get_node("/root/scene").add_child.call_deferred(saver)

	# Add the mastery to The Crystalline.
	if global.map == "the_crystalline":
		var collectable_prefab = preload("res://objects/nodes/collectable.tscn")
		var saver_prefab = preload("res://objects/nodes/saver.tscn")
		var tpl_prefab = preload("res://objects/nodes/listeners/teleportListener.tscn")

		var mastery = collectable_prefab.instantiate()
		mastery.name = "collectable"
		mastery.position = Vector3(0, 13, 37)
		mastery.unlock_type = "smiley"
		mastery.material_override = load("res://assets/materials/gold.material")
		get_node("/root/scene/Components/Collectables").add_child.call_deferred(mastery)

		var tpl = tpl_prefab.instantiate()
		tpl.teleport_point = Vector3(0, 11.5, -20)
		tpl.teleport_rotate = Vector3(0, 0, 180)
		tpl.target_path = mastery
		tpl.name = "Teleport"
		tpl.senders.append(NodePath("/root/scene/Panels/Room_1/panel_3"))
		mastery.add_child.call_deferred(tpl)

		var saver = saver_prefab.instantiate()
		saver.name = "saver_collectables"
		saver.type = "collectables"
		saver.senderGroup.append(NodePath("/root/scene/Components/Collectables"))
		get_node("/root/scene").add_child.call_deferred(saver)

	ap.update_job_well_done_sign()

	# Set up door locations.
	var map_id = gamedata.map_id_by_name.get(global.map)
	for door in gamedata.objects.get_doors():
		if door.get_map_id() != map_id:
			continue

		if not door.has_ap_id():
			continue

		if (
			door.get_type() == gamedata.SCRIPT_proto.DoorType.ITEM_ONLY
			or door.get_type() == gamedata.SCRIPT_proto.DoorType.GALLERY_PAINTING
			or door.get_type() == gamedata.SCRIPT_proto.DoorType.CONTROL_CENTER_COLOR
		):
			continue

		var locationListener = ap.SCRIPT_locationListener.new()
		locationListener.location_id = door.get_ap_id()
		locationListener.name = "locationListener_%d" % door.get_ap_id()

		for panel_ref in door.get_panels():
			var panel_data = gamedata.objects.get_panels()[panel_ref.get_panel()]
			var panel_path = panel_data.get_path()

			if panel_ref.has_answer():
				for proxy in panel_data.get_proxies():
					if proxy.get_answer() == panel_ref.get_answer():
						panel_path = proxy.get_path()
						break

			locationListener.senders.append(NodePath("/root/scene/" + panel_path))

		for keyholder_ref in door.get_keyholders():
			var keyholder_data = gamedata.objects.get_keyholders()[keyholder_ref.get_keyholder()]

			var khl = khl_script.new()
			khl.name = (
				"location_%d_keyholder_%d" % [door.get_ap_id(), keyholder_ref.get_keyholder()]
			)
			khl.answer = keyholder_ref.get_key()
			khl.senders.append(NodePath("/root/scene/" + keyholder_data.get_path()))
			get_parent().add_child.call_deferred(khl)

			locationListener.senders.append(NodePath("../" + khl.name))

		for sender in door.get_senders():
			locationListener.senders.append(NodePath("/root/scene/" + sender))

		if door.has_complete_at():
			locationListener.complete_at = door.get_complete_at()

		get_parent().add_child.call_deferred(locationListener)

	# Set up letter locations.
	for letter in gamedata.objects.get_letters():
		var room = gamedata.objects.get_rooms()[letter.get_room_id()]
		if room.get_map_id() != map_id:
			continue

		var locationListener = ap.SCRIPT_locationListener.new()
		locationListener.location_id = letter.get_ap_id()
		locationListener.name = "locationListener_%d" % letter.get_ap_id()
		locationListener.senders.append(NodePath("/root/scene/" + letter.get_path()))

		get_parent().add_child.call_deferred(locationListener)

		if (
			ap.get_letter_behavior(letter.get_key(), letter.has_level2() and letter.get_level2())
			!= ap.kLETTER_BEHAVIOR_VANILLA
		):
			var scout = ap.scout_location(letter.get_ap_id())
			if scout != null and not (scout["for_self"] and scout["flags"] & 4 != 0):
				var collectable = get_tree().get_root().get_node("scene").get_node_or_null(
					letter.get_path()
				)
				if collectable != null:
					collectable.setScoutedText.call_deferred(scout["item"])

	# Set up mastery locations.
	for mastery in gamedata.objects.get_masteries():
		var room = gamedata.objects.get_rooms()[mastery.get_room_id()]
		if room.get_map_id() != map_id:
			continue

		var locationListener = ap.SCRIPT_locationListener.new()
		locationListener.location_id = mastery.get_ap_id()
		locationListener.name = "locationListener_%d" % mastery.get_ap_id()
		locationListener.senders.append(NodePath("/root/scene/" + mastery.get_path()))

		get_parent().add_child.call_deferred(locationListener)

	# Set up ending locations.
	for ending in gamedata.objects.get_endings():
		var room = gamedata.objects.get_rooms()[ending.get_room_id()]
		if room.get_map_id() != map_id:
			continue

		var locationListener = ap.SCRIPT_locationListener.new()
		locationListener.location_id = ending.get_ap_id()
		locationListener.name = "locationListener_%d" % ending.get_ap_id()
		locationListener.senders.append(NodePath("/root/scene/" + ending.get_path()))

		get_parent().add_child.call_deferred(locationListener)

		if ap.kEndingNameByVictoryValue.get(ap.victory_condition, null) == ending.get_name():
			var victoryListener = ap.SCRIPT_victoryListener.new()
			victoryListener.name = "victoryListener"
			victoryListener.senders.append(NodePath("/root/scene/" + ending.get_path()))

			get_parent().add_child.call_deferred(victoryListener)

	# Set up keyholder locations, in keyholder sanity.
	if ap.keyholder_sanity:
		for keyholder in gamedata.objects.get_keyholders():
			if not keyholder.has_key():
				continue

			var room = gamedata.objects.get_rooms()[keyholder.get_room_id()]
			if room.get_map_id() != map_id:
				continue

			var locationListener = ap.SCRIPT_locationListener.new()
			locationListener.location_id = keyholder.get_ap_id()
			locationListener.name = "locationListener_%d" % keyholder.get_ap_id()

			var khl = khl_script.new()
			khl.name = "location_%d_keyholder" % keyholder.get_ap_id()
			khl.answer = keyholder.get_key()
			khl.senders.append(NodePath("/root/scene/" + keyholder.get_path()))
			get_parent().add_child.call_deferred(khl)

			locationListener.senders.append(NodePath("../" + khl.name))

			get_parent().add_child.call_deferred(locationListener)

	var minimap = ap.SCRIPT_minimap.new()
	minimap.name = "Minimap"
	minimap.visible = ap.show_minimap
	get_parent().add_child.call_deferred(minimap)

	super._ready()

	await get_tree().process_frame
	await get_tree().process_frame

	ap.stop_batching_locations()


func _set_up_invis_wall(x, y, z, sx, sy, sz):
	var prefab = preload("res://objects/nodes/block.tscn")
	var newwall = prefab.instantiate()
	newwall.position.x = x
	newwall.position.y = y
	newwall.position.z = z
	newwall.scale.x = sz
	newwall.scale.y = sy
	newwall.scale.z = sx
	newwall.set_surface_override_material(0, preload("res://assets/materials/blackMatte.material"))
	newwall.visibility_range_end = 3
	newwall.visibility_range_end_margin = 1
	newwall.visibility_range_fade_mode = RenderingServer.VISIBILITY_RANGE_FADE_SELF
	newwall.skeleton = ".."
	get_parent().add_child.call_deferred(newwall)


func _process(_dt):
	compass.update_rotation(global_rotation.y)