data/maps/the_gallery/rooms/Back Room.txtpb


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16

name: "Back Room"
panels {
  name: "UNYIELDING"
  path: "Panels/entry_2"
  clue: ""
  answer: "jab"
  symbols: QUESTION
}
panels {
  name: "TREE"
  path: "Panels/entry_3"
  clue: ""
  answer: "icy"
  symbols: QUESTION
}
# Not sure whether the two paintings in here should be randomized, since they're hints.
extends Node


func _ready():
	var runtime = global.get_node("Runtime")

	# Some helpful logging.
	if Steam.isSubscribed():
		global._print("Provisioning successful! Build ID: %d" % Steam.getAppBuildId())
	else:
		global._print("Provisioning failed.")

	# Undo the load screen removing our cursor
	get_tree().get_root().set_disable_input(false)
	Input.set_mouse_mode(Input.MOUSE_MODE_VISIBLE)

	# Increase the WebSocket input buffer size so that we can download large
	# data packages.
	ProjectSettings.set_setting("network/limits/websocket_client/max_in_buffer_kb", 8192)

	switcher.layer = 4

	# Create the global AP manager, if it doesn't already exist.
	if not global.has_node("Archipelago"):
		var ap_script = runtime.load_script("manager.gd")
		var ap_instance = ap_script.new()
		ap_instance.name = "Archipelago"

		ap_instance.SCRIPT_client = runtime.load_script("client.gd")
		ap_instance.SCRIPT_keyboard = runtime.load_script("keyboard.gd")
		ap_instance.SCRIPT_locationListener = runtime.load_script("locationListener.gd")
		ap_instance.SCRIPT_minimap = runtime.load_script("minimap.gd")
		ap_instance.SCRIPT_victoryListener = runtime.load_script("victoryListener.gd")
		ap_instance.SCRIPT_websocketserver = runtime.load_script("vendor/WebSocketServer.gd")

		global.add_child(ap_instance)

		# Let's also inject any scripts we need to inject now.
		installScriptExtension(runtime.load_script("allowNumbers.gd"))
		installScriptExtension(runtime.load_script("animationListener.gd"))
		installScriptExtension(runtime.load_script("collectable.gd"))
		installScriptExtension(runtime.load_script("door.gd"))
		installScriptExtension(runtime.load_script("keyHolder.gd"))
		installScriptExtension(runtime.load_script("keyHolderChecker.gd"))
		installScriptExtension(runtime.load_script("keyHolderResetterListener.gd"))
		installScriptExtension(runtime.load_script("painting.gd"))
		installScriptExtension(runtime.load_script("paintingAuto.gd"))
		installScriptExtension(runtime.load_script("panel.gd"))
		installScriptExtension(runtime.load_script("pauseMenu.gd"))
		installScriptExtension(runtime.load_script("player.gd"))
		installScriptExtension(runtime.load_script("rteMenu.gd"))
		installScriptExtension(runtime.load_script("saver.gd"))
		installScriptExtension(runtime.load_script("teleport.gd"))
		installScriptExtension(runtime.load_script("teleportListener.gd"))
		installScriptExtension(runtime.load_script("unlockReaderListener.gd"))
		installScriptExtension(runtime.load_script("visibilityListener.gd"))
		installScriptExtension(runtime.load_script("worldport.gd"))
		installScriptExtension(runtime.load_script("worldportListener.gd"))

		var proto_script = runtime.load_script("../generated/proto.gd")
		var gamedata_script = runtime.load_script("gamedata.gd")
		var gamedata_instance = gamedata_script.new(proto_script)
		gamedata_instance.load(runtime.read_path("../generated/data.binpb"))
		gamedata_instance.name = "Gamedata"
		global.add_child(gamedata_instance)

		var messages_script = runtime.load_script("messages.gd")
		var messages_instance = messages_script.new()
		messages_instance.name = "Messages"
		messages_instance.SCRIPT_rainbowText = runtime.load_script("rainbowText.gd")
		global.add_child(messages_instance)

		var effects_script = runtime.load_script("effects.gd")
		var effects_instance = effects_script.new()
		effects_instance.name = "Effects"
		global.add_child(effects_instance)

		var textclient_script = runtime.load_script("textclient.gd")
		var textclient_instance = textclient_script.new()
		textclient_instance.name = "Textclient"
		global.add_child(textclient_instance)

		var compass_overlay_script = runtime.load_script("compass_overlay.gd")
		var compass_overlay_instance = compass_overlay_script.new()
		compass_overlay_instance.name = "Compass"
		compass_overlay_instance.SCRIPT_compass = runtime.load_script("compass.gd")
		global.add_child(compass_overlay_instance)

		unlocks.data["advanced_mastery"] = ""
		unlocks.data["charismatic_mastery"] = ""
		unlocks.data["crystalline_mastery"] = ""
		unlocks.data["fuzzy_mastery"] = ""
		unlocks.data["icarus_mastery"] = ""
		unlocks.data["stellar_mastery"] = ""

	var ap = global.get_node("Archipelago")
	var gamedata = global.get_node("Gamedata")
	ap.ap_connected.connect(connectionSuccessful)
	ap.could_not_connect.connect(connectionUnsuccessful)
	ap.connect_status.connect(connectionStatus)

	# Populate textboxes with AP settings.
	get_node("../Panel/server_box").text = ap.ap_server
	get_node("../Panel/player_box").text = ap.ap_user
	get_node("../Panel/password_box").text = ap.ap_pass

	var history_box = get_node("../Panel/connection_history")
	if ap.connection_history.is_empty():
		history_box.disabled = true
	else:
		history_box.disabled = false

		var i = 0
		for details in ap.connection_history:
			history_box.get_popup().add_item("%s (%s)" % [details[1], details[0]], i)
			i += 1

	history_box.get_popup().id_pressed.connect(historySelected)

	# Show client version.
	var version = gamedata.objects.get_version()
	get_node("../Panel/title").text = (
		"ARCHIPELAGO (%d.%d.%d)" % [version.get_major(), version.get_minor(), version.get_patch()]
	)

	# Increase font size in text boxes.
	get_node("../Panel/server_box").add_theme_font_size_override("font_size", 36)
	get_node("../Panel/player_box").add_theme_font_size_override("font_size", 36)
	get_node("../Panel/password_box").add_theme_font_size_override("font_size", 36)

	# Set up version mismatch dialog.
	get_node("../Panel/VersionMismatch").confirmed.connect(startGame)
	get_node("../Panel/VersionMismatch").get_cancel_button().pressed.connect(
		versionMismatchDeclined
	)

	# Set up buttons.
	get_node("../Panel/connect_button").pressed.connect(_connect_pressed)
	get_node("../Panel/quit_button").pressed.connect(_back_pressed)


func _connect_pressed():
	get_node("../Panel/connect_button").disabled = true

	var ap = global.get_node("Archipelago")
	ap.ap_server = get_node("../Panel/server_box").text
	ap.ap_user = get_node("../Panel/player_box").text
	ap.ap_pass = get_node("../Panel/password_box").text
	ap.saveSettings()

	ap.connectToServer()


func _back_pressed():
	var ap = global.get_node("Archipelago")
	ap.disconnect_from_ap()
	ap.client.sendQuit()

	get_tree().quit()


# Adapted from https://gitlab.com/Delta-V-Modding/Mods/-/blob/main/game/ModLoader.gd
func installScriptExtension(childScript: Resource):
	# Force Godot to compile the script now.
	# We need to do this here to ensure that the inheritance chain is
	# properly set up, and multiple mods can chain-extend the same
	# class multiple times.
	# This is also needed to make Godot instantiate the extended class
	# when creating singletons.
	# The actual instance is thrown away.
	childScript.new()

	var parentScript = childScript.get_base_script()
	var parentScriptPath = parentScript.resource_path
	global._print("ModLoader: Installing script extension over %s" % parentScriptPath)
	childScript.take_over_path(parentScriptPath)


func connectionStatus(message):
	var popup = get_node("../Panel/AcceptDialog")
	popup.title = "Connecting to Archipelago"
	popup.dialog_text = message
	popup.exclusive = true
	popup.get_ok_button().visible = false
	popup.popup_centered()


func connectionSuccessful():
	var ap = global.get_node("Archipelago")
	var gamedata = global.get_node("Gamedata")

	# Check for major version mismatch.
	if ap.apworld_version[0] != gamedata.objects.get_version().get_major():
		get_node("../Panel/AcceptDialog").exclusive = false

		var popup = get_node("../Panel/VersionMismatch")
		popup.title = "Version Mismatch!"
		popup.dialog_text = (
			"This slot was generated using v%d.%d.%d of the Lingo 2 apworld,\nwhich has a different major version than this client (v%d.%d.%d).\nIt is highly recommended to play using the correct version of the client.\nYou may experience bugs or logic issues if you continue."
			% [
				ap.apworld_version[0],
				ap.apworld_version[1],
				ap.apworld_version[2],
				gamedata.objects.get_version().get_major(),
				gamedata.objects.get_version().get_minor(),
				gamedata.objects.get_version().get_patch()
			]
		)
		popup.exclusive = true
		popup.popup_centered()

		return

	startGame()


func startGame():
	var ap = global.get_node("Archipelago")

	# Save connection details
	var connection_details = [ap.ap_server, ap.ap_user, ap.ap_pass]
	if ap.connection_history.has(connection_details):
		ap.connection_history.erase(connection_details)
	ap.connection_history.push_front(connection_details)
	if ap.connection_history.size() > 10:
		ap.connection_history.resize(10)
	ap.saveSettings()

	# Switch to the_entry
	Input.set_mouse_mode(Input.MOUSE_MODE_CAPTURED)
	global.user = ap.getSaveFileName()
	global.universe = "lingo"

	if ap.daedalus_only:
		global.map = "daedalus"
	else:
		global.map = "the_entry"

	unlocks.resetCollectables()
	unlocks.resetData()
	unlocks.loadCollectables()
	unlocks.loadData()

	ap.setup_keys()

	unlocks.unlockKey("capslock", 1)

	if ap.shuffle_worldports:
		settings.worldport_fades = "default"
	else:
		settings.worldport_fades = "never"

	clearResourceCache("res://objects/meshes/gridDoor.tscn")
	clearResourceCache("res://objects/nodes/allowNumbers.tscn")
	clearResourceCache("res://objects/nodes/collectable.tscn")
	clearResourceCache("res://objects/nodes/door.tscn")
	clearResourceCache("res://objects/nodes/keyHolder.tscn")
	clearResourceCache("res://objects/nodes/listeners/animationListener.tscn")
	clearResourceCache("res://objects/nodes/listeners/keyHolderChecker.tscn")
	clearResourceCache("res://objects/nodes/listeners/keyHolderResetterListener.tscn")
	clearResourceCache("res://objects/nodes/listeners/teleportListener.tscn")
	clearResourceCache("res://objects/nodes/listeners/unlockReaderListener.tscn")
	clearResourceCache("res://objects/nodes/listeners/visibilityListener.tscn")
	clearResourceCache("res://objects/nodes/listeners/worldportListener.tscn")
	clearResourceCache("res://objects/nodes/panel.tscn")
	clearResourceCache("res://objects/nodes/player.tscn")
	clearResourceCache("res://objects/nodes/saver.tscn")
	clearResourceCache("res://objects/nodes/teleport.tscn")
	clearResourceCache("res://objects/nodes/worldport.tscn")
	clearResourceCache("res://objects/scenes/menus/pause_menu.tscn")
	clearResourceCache("res://objects/scenes/menus/rte_inner.tscn")

	var paintings_dir = DirAccess.open("res://objects/meshes/paintings")
	if paintings_dir:
		paintings_dir.list_dir_begin()
		var file_name = paintings_dir.get_next()
		while file_name != "":
			if not paintings_dir.current_is_dir() and file_name.ends_with(".tscn"):
				clearResourceCache("res://objects/meshes/paintings/" + file_name)
			file_name = paintings_dir.get_next()

	switcher.switch_map.call_deferred("res://objects/scenes/%s.tscn" % global.map)


func connectionUnsuccessful(error_message):
	get_node("../Panel/connect_button").disabled = false

	var popup = get_node("../Panel/AcceptDialog")
	popup.title = "Could not connect to Archipelago"
	popup.dialog_text = error_message
	popup.exclusive = true
	popup.get_ok_button().visible = true
	popup.popup_centered()


func versionMismatchDeclined():
	get_node("../Panel/AcceptDialog").hide()
	get_node("../Panel/connect_button").disabled = false

	var ap = global.get_node("Archipelago")
	ap.disconnect_from_ap()


func historySelected(index):
	var ap = global.get_node("Archipelago")
	var details = ap.connection_history[index]

	get_node("../Panel/server_box").text = details[0]
	get_node("../Panel/player_box").text = details[1]
	get_node("../Panel/password_box").text = details[2]


func clearResourceCache(path):
	ResourceLoader.load(path, "", ResourceLoader.CACHE_MODE_REPLACE)