extends "res://scripts/nodes/panel.gd"

var panel_logic = null
var symbol_solvable = true

var black = load("res://assets/materials/black.material")


func _ready():
	super._ready()

	var node_path = String(
		get_tree().get_root().get_node("scene").get_path_to(self).get_concatenated_names()
	)

	var gamedata = global.get_node("Gamedata")
	var panel_id = gamedata.get_panel_for_map_node_path(global.map, node_path)
	if panel_id != null:
		var ap = global.get_node("Archipelago")
		if ap.shuffle_symbols:
			if global.map == "the_entry" and node_path == "Panels/Entry/front_1":
				clue = "i"
				symbol = ""

				setField("clue", clue)
				setField("symbol", symbol)

		panel_logic = gamedata.objects.get_panels()[panel_id]
		checkSymbolSolvable()

		if not symbol_solvable:
			get_tree().get_root().get_node("scene/player").connect(
				"evaluate_solvability", evaluateSolvability
			)


func checkSymbolSolvable():
	var old_solvable = symbol_solvable
	symbol_solvable = true

	if panel_logic == null:
		# There's no logic for this panel.
		return

	var ap = global.get_node("Archipelago")
	if not ap.shuffle_symbols:
		# Symbols aren't item-locked.
		return

	var gamedata = global.get_node("Gamedata")
	for symbol in panel_logic.get_symbols():
		var item_name = gamedata.kSYMBOL_ITEMS.get(symbol)
		var item_id = gamedata.objects.get_special_ids()[item_name]
		if ap.client.getItemAmount(item_id) < 1:
			symbol_solvable = false
			break

	if symbol_solvable != old_solvable:
		if symbol_solvable:
			setField("clue", clue)
			setField("symbol", symbol)
			setField("answer", answer)
		else:
			quad_mesh.surface_set_material(0, black)
			get_node("Hinge/clue").text = "missing"
			get_node("Hinge/answer").text = "symbols"


func checkSolvable(key):
	checkSymbolSolvable()
	if not symbol_solvable:
		return false

	return super.checkSolvable(key)


func evaluateSolvability():
	checkSolvable("")


func passedInput(key, skip_focus_check = false):
	if not symbol_solvable:
		return

	super.passedInput(key, skip_focus_check)


func focus():
	if not symbol_solvable:
		has_focus = false
		return

	super.focus()


func unfocus():
	if not symbol_solvable:
		has_focus = false
		return

	super.unfocus()