extends "res://scripts/nodes/door.gd"

var door_id
var item_id
var item_amount
var latched = false


func _ready():
	var node_path = String(
		get_tree().get_root().get_node("scene").get_path_to(self).get_concatenated_names()
	)

	var gamedata = global.get_node("Gamedata")
	door_id = gamedata.get_door_for_map_node_path(global.map, node_path)
	if door_id != null:
		var ap = global.get_node("Archipelago")
		var item_lock = ap.get_item_id_for_door(door_id)

		if item_lock != null:
			item_id = item_lock[0]
			item_amount = item_lock[1]

			self.senders = []
			self.senderGroup = []
			self.nested = false
			self.complete_at = 0
			self.max_length = 0
			self.excludeSenders = []

			call_deferred("_readier")
		else:
			var door_data = gamedata.objects.get_doors()[door_id]
			if door_data.has_latch() and door_data.get_latch():
				_check_latched.call_deferred(door_id)

				latched = true

	if global.map == "the_sun_temple":
		if name == "spe_EndPlatform" or name == "spe_entry_2":
			senders = [NodePath("/root/scene/Panels/EndCheck_dog")]

	if global.map == "the_parthenon":
		if name == "spe_entry_1":
			senders = [NodePath("/root/scene/Panels/EndCheck_dog")]

	super._ready()


func _readier():
	var ap = global.get_node("Archipelago")

	if ap.client.getItemAmount(item_id) >= item_amount:
		handleTriggered()


func _check_latched(door_id):
	var ap = global.get_node("Archipelago")

	if ap.client._latched_doors.has(door_id):
		triggered = total
		handleTriggered()


func handleTriggered():
	super.handleTriggered()

	if latched and ran:
		var ap = global.get_node("Archipelago")
		ap.client.latchDoor(door_id)


func handleUntriggered():
	if not latched or not ran:
		super.handleUntriggered()