about summary refs log tree commit diff stats
path: root/data/maps/the_talented/rooms
diff options
context:
space:
mode:
authorStar Rauchenberger <fefferburbia@gmail.com>2025-09-14 13:37:58 -0400
committerStar Rauchenberger <fefferburbia@gmail.com>2025-09-14 13:37:58 -0400
commitad4f4bdb06897a038fdbe3ebd50de1c33d900594 (patch)
treeca466ab932ab9c05a960c7488750dbe796306b88 /data/maps/the_talented/rooms
parentdaa2961e096e6e9051b30f9c9052cdd8c2dfd976 (diff)
downloadlingo2-archipelago-ad4f4bdb06897a038fdbe3ebd50de1c33d900594.tar.gz
lingo2-archipelago-ad4f4bdb06897a038fdbe3ebd50de1c33d900594.tar.bz2
lingo2-archipelago-ad4f4bdb06897a038fdbe3ebd50de1c33d900594.zip
Released Apworld v4.4
Diffstat (limited to 'data/maps/the_talented/rooms')
0 files changed, 0 insertions, 0 deletions
 

generated by cgit-pink 1.4.1 (git 2.36.1) at 2026-03-03 18:18:20 +0000


 


>
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186


extends Node

var activated = false
var effect_running = false
var slowness_remaining = 0
var iceland_remaining = 0
var atbash_activated = false
var queued_iceland = 0
var skip_available = false
var puzzle_focused = false
var solve_mode = false
var puzzle_to_skip = ""

var orig_env
var orig_walk
var orig_run


func _ready():
	orig_env = get_tree().get_root().get_node("Spatial/player/pivot/camera").environment
	orig_walk = get_tree().get_root().get_node("Spatial/player").walk_speed
	orig_run = get_tree().get_root().get_node("Spatial/player").run_speed

	var label = Label.new()
	label.set_name("label")
	label.margin_right = 1920.0 - 20.0
	label.margin_top = 20.0
	label.align = Label.ALIGN_RIGHT
	label.valign = Label.VALIGN_TOP

	var dynamic_font = DynamicFont.new()
	dynamic_font.font_data = load("res://fonts/Lingo.ttf")
	dynamic_font.size = 36
	dynamic_font.outline_color = Color(0, 0, 0, 1)
	dynamic_font.outline_size = 2
	label.add_font_override("font", dynamic_font)

	add_child(label)


func activate():
	activated = true

	for _i in range(0, queued_iceland):
		trigger_iceland_trap()

	queued_iceland = 0


func trigger_slowness_trap():
	if slowness_remaining == 0:
		var player = get_tree().get_root().get_node("Spatial/player")
		player.walk_speed = orig_walk / 2.0
		player.run_speed = orig_run / 2.0

	slowness_remaining += 30

	if not effect_running:
		_process_effects()


func trigger_iceland_trap():
	if not activated:
		queued_iceland += 1
		return

	if iceland_remaining == 0:
		get_tree().get_root().get_node("Spatial/player/pivot/camera").set_environment(
			load("res://environments/level_iceland.tres")
		)

	iceland_remaining += 60

	if not effect_running:
		_process_effects()


func trigger_atbash_trap():
	if not atbash_activated:
		atbash_activated = true

		var apclient = global.get_node("Archipelago")
		apclient.evaluateSolvability()

	if not effect_running:
		_process_effects()


func deactivate_atbash_trap():
	if atbash_activated:
		atbash_activated = false

		var apclient = global.get_node("Archipelago")
		apclient.evaluateSolvability()


func show_puzzle_skip_message(node_path):
	var panel_input = get_tree().get_root().get_node(node_path)
	if not panel_input.visible:
		return

	var ap_panel = panel_input.get_parent().get_parent().get_parent().get_parent().get_node(
		"AP_Panel"
	)
	if not ap_panel.solvable:
		return

	puzzle_focused = true
	puzzle_to_skip = node_path
	_evaluate_puzzle_skip()


func hide_puzzle_skip_message():
	puzzle_focused = false
	_evaluate_puzzle_skip()


func enter_solve_mode():
	solve_mode = true
	_evaluate_puzzle_skip()


func exit_solve_mode():
	solve_mode = false
	_evaluate_puzzle_skip()


func skip_puzzle():
	if not solve_mode and puzzle_focused:
		var apclient = global.get_node("Archipelago")
		if apclient.getAvailablePuzzleSkips() > 0:
			apclient.usePuzzleSkip()
			get_tree().get_root().get_node(puzzle_to_skip).complete()


func _evaluate_puzzle_skip():
	if puzzle_focused and not solve_mode:
		skip_available = true

		if not effect_running:
			_process_effects()
	else:
		skip_available = false


func _process_effects():
	effect_running = true

	while slowness_remaining > 0 or iceland_remaining > 0 or atbash_activated or skip_available:
		var text = ""
		if atbash_activated:
			text += "Atbash Trap lasts until you solve a puzzle"
		if skip_available:
			var apclient = global.get_node("Archipelago")
			if apclient.getAvailablePuzzleSkips() > 0:
				text += "Press P to skip puzzle (%d available)" % apclient.getAvailablePuzzleSkips()
		if slowness_remaining > 0:
			if not text.empty():
				text += "\n"
			text += "Slowness: %d seconds" % slowness_remaining
		if iceland_remaining > 0:
			if not text.empty():
				text += "\n"
			text += "Iceland: %d seconds" % iceland_remaining
		self.get_node("label").text = text

		yield(get_tree().create_timer(1.0), "timeout")

		if slowness_remaining > 0:
			slowness_remaining -= 1

			if slowness_remaining == 0:
				var player = get_tree().get_root().get_node("Spatial/player")
				player.walk_speed = orig_walk
				player.run_speed = orig_run

		if iceland_remaining > 0:
			iceland_remaining -= 1

			if iceland_remaining == 0:
				get_tree().get_root().get_node("Spatial/player/pivot/camera").set_environment(
					orig_env
				)

	self.get_node("label").text = ""
	effect_running = false